10 REM ......................HERMITE POLYNOMINALS                      
REM GE Copeland
REM Dept of Physics
REM Old Dominion University
REM Norfolk VA 23529
REM - Corrin Wilson 3/13/2001
REM


20 DIM Y(300)
50 DIM H(32)
60 DEF fnh (N, X)
70 H(0) = 1
80 H(1) = 2 * X
90 IF N = 0 THEN 140
100 IF N = 1 THEN 140
110 FOR K = 2 TO N
120 H(K) = 2 * X * H(K - 1) - 2 * (K - 1) * H(K - 2)
130 NEXT K
140 fnh = H(N)
150 END DEF
151 PRINT CHR$(12);
160 PRINT "THIS PROGRAM CALCULATES THE VALUE OF THE HERMITE POLYNOMINALS"
170 PRINT "FOR N=0 TO 10 GIVEN A VALUE OF X."
171 PRINT "THE FIRST FEW FUNCTIONS ARE:"
172 PRINT "H(0,X)=1"
173 PRINT "H(1,X)=2*X"
174 PRINT "H(2,X)=4*X^2-2"
175 PRINT "H(3,X)=8*X^3-12*X"
176 PRINT "ETC....."
177 PRINT "NOTE THESE FUNCTIONS ARE ODD OR EVEN IF N IS ODD OR EVEN."
178 PRINT "ALL VALUES ARE DETERMINED IN THIS PROGRAM USING THE RECURSION FORMUL"
179 PRINT , " H( N+1 ,X) - 2 * X * H( N ,X) + 2 * N * H( N-1 ,X) = 0"
180 PRINT "INPUT THE VALUE OF X";
190 INPUT X
200 PRINT "H(N)", "N", "X"
210 FOR N = 0 TO 10
220 PRINT fnh(N, X), N, X
230 NEXT N
240 PRINT " DO YOU WANT VALUES FOR ANOTHER X";
250 INPUT a2$
260 IF a2$ = "YES" OR a2$ = "Yes" OR a2$ = "yes" THEN GOTO 180
270 REM                                                                     
280 REM                                                                     
290 PRINT "NOW LET'S PLOT THE VALUES OF THE HERMITE POLYNOMINALS."
300 PRINT "WE WILL CALCULATE THE VALUES OF THE FUNCTIONS OVER A RANGE"
310 PRINT "OF VALUES XMIN TO XMAX FOR A SINGLE  H( N,X)."
320 PRINT "INPUT THE LOWER LIMIT OF X";
330 INPUT X1
340 PRINT "INPUT THE UPPER LIMIT";
350 INPUT X2
360 PRINT
370 PRINT "INPUT THE N VALUE FOR THE HERMITE POLYNOMINAL YOU WISH TO SEE";
380 INPUT N
382 PRINT "DO YOU WISH TO SEE THE NUMERICAL VALUES";
384 INPUT B$
386 IF B$ = "NO" OR B$ = "no" OR B$ = "No" THEN GOTO 390
388 PRINT "H("; N; ")", "X"
390 J = 0
400 X3 = (X2 + ABS(X1)) / 250!
420 FOR X = X1 TO X2 STEP X3
430 J = J + 1
440 Y(J) = fnh(N, X)
441 IF B$ = "NO" OR B$ = "no" OR B$ = "No" THEN GOTO 450
442 PRINT X, Y(J)
450 NEXT X
460 PRINT "Do you want graphical output? (Yes = plot for WPlot, No = Quit)"
470 INPUT a2$
490 IF a2$ = "YES" OR a2$ = "yes" OR a2$ = "Yes" THEN GOTO 530
491 IF a2$ = "NO" OR a2$ = "no" OR a2$ = "No" THEN GOTO 670
500 PRINT "I DON'T UNDERSTAND YOUR ANSWER."
510  GOTO 460
520 REM J IS NUMBER OF POINTS                                               
530 OPEN "Plttek.dat" FOR OUTPUT AS #2
540 PRINT #2, 1
550 PRINT #2, 1
560 PRINT #2, J
570 PRINT #2, "           VALUE OF FUNCTION"
580 PRINT #2, " POSITION    X AXIS----->"
590 PRINT #2, "         HERMITE POLYNOMINALS H("; N; ",X)"
600 PRINT #2, "       OVER RANGE X="; X1; " TO "; X2
610 I = 0
620 FOR X = X1 TO X2 STEP X3
630 I = I + 1
640 PRINT #2, X, Y(I)
650 NEXT X
660 PRINT "Open Plot.plt in WPlot to view graph."
662 CLOSE #2
665 GOTO 800
670 STOP
                
800 CHAIN "Tek2WPlt.exe"
810 END