DECLARE SUB Pager ()
REM
REM GE Copeland
REM Old Dominion University
REM Dept of Physics
REM Norfolk VA
REM updated for windows
REM 4/2001
REM
5 PRINT CHR$(12);
10 PRINT "PROGRAM MAY"
20 PRINT
30 PRINT " This program follows the discovery of Robert May in his study"
40 PRINT "of a species population growth as reported in James Gleick's"
50 PRINT "popular text 'CHAOS, MAKING A NEW SCIENCE.'"
60 PRINT
70 PRINT "We let X be the normalized population in any generation."
80 PRINT "We wish to predict the value of X ( 0<X<1 ) in the next generation."
90 PRINT "Various models exist for this problem.  We select a very simple"
100 PRINT "one to study. It is a simple modification of a linear growth system."
110 PRINT
120 PRINT " We let X(next) = r X(now)*( 1-X(now) )"
130 PRINT
140 PRINT "We pick a seed value for X(now) and an arbitrary value for r."
150 PRINT "Now the fun begins!"
160 CALL Pager
170 PRINT " It was discovered for small values of r, say 2.7, the number in"
180 PRINT "the next generation X(next) when plotted vs generation number "
190 PRINT "tends to start at the seed value (say 0.02) and approach a limit"
200 PRINT "value.  The plot looks like a square wave with a slow rise time"
210 PRINT "with a ring that dies out --- if you have used an oscilloscope"
220 PRINT "you have the picture. Otherwize look at the figure in Gleick"
230 PRINT "on page 67."
240 PRINT
250 PRINT " HOWEVER, as r increases to larger values, STRANGE THINGS HAPPEN !"
260 PRINT "We see that the number in a generation starts to be periodic. "
270 PRINT "We see a period doubling behavior. That is, the number in a "
280 PRINT "generation oscillates with generation number. This is best seen"
290 PRINT "in the long term solution of the equation after many generations."
300 PRINT " That is, after many generations (~300), the number in the"
310 PRINT "next generation is not constant, but tends toward one of two"
320 PRINT "values.  As r is increased more, we see period triples, etc."
330 CALL Pager
340 PRINT " We will now calculate the generations for seed values of 0.02"
350 PRINT "You will see many different screens. Each will be for different"
360 PRINT "values for the factor r.  We will sart with r low and increase it."
370 PRINT "We will run the equation through 300 generations in order that all"
380 PRINT "transients (rings) die out. We will keep the population numbers"
390 PRINT "of the last 101 generations.  Next we find the max and min of"
400 PRINT "the species. Then we do a sort and put this distribution into bins"
410 PRINT "between X=0 and X=1.  For small values of r we see a sharp"
420 PRINT "distribution, as r gets bigger, the distribution splits, and "
430 PRINT "splits,..... UNTIL there is CHAOS!"
440 CALL Pager
                                                                     
1000 DIM XIN(101)
1010 PRINT CHR$(12)
1020 J = 0
1030  FOR R = 1! TO 4! STEP .1
1040 X = .02
1050 I = 1
1060 IEND = 300
1070                                                                         
1080 XNEW = R * X * (1! - X)
1090 I = I + 1
1100 X = XNEW
1110 IF I > IEND - 100 THEN J = J + 1
1120 IF J > 0 THEN XIN(J) = XNEW
1130 IF I > IEND THEN 1150
1140 GOTO 1080
1150 REM GET READY TO CALL HISTOGRAM SORTING ROUTINE                         
1160 NPTS = J
1170  GOSUB 1210
1180 J = 0
1190 NEXT R
1200 PRINT " End of simulation"
STOP
1210 REM PROC HISTO                                                          
1220 CALL Pager
1230 PRINT " R="; R
1240 DIM X(300), Y(300)
1250 DIM YIN(300)
1260 REM                                                                     
1270 REM INPUT IS XIN WITH NPTS DATA POINTS                                  
1280 REM FIND MAX AND MIN                                                    
1290 XMIN = 9.999999E+35
1300 XMAX = -XMIN
1310 FOR I = 1 TO NPTS
1320 IF XIN(I) > XMAX THEN XMAX = XIN(I)
1330 IF XIN(I) < XMIN THEN XMIN = XIN(I)
1340 NEXT I
1350 PRINT "MAX value "; XMAX; "& MIN value "; XMIN;
1360                                                                         
1370 REM  "Input the bin size?"                                              
1380 REM INPUT BIN                                                           
1390 NBIN = 18
1400 BIN = 1! / 18!
1410 PRINT  '# bins =';NBIN                                                   
1420  REM Now we start the sort and fill the bins                            
1430 FOR I = 1 TO NBIN + 2
1440 X(I) = (I - 1) * BIN
1450 Y(I) = 0
1460 NEXT I
1470 FOR I = 1 TO NBIN + 1
1480 FOR J = 1 TO NPTS
1490 IF XIN(J) >= X(I) AND XIN(J) < X(I + 1) THEN Y(I) = Y(I) + 1
1500 NEXT J
1510 NEXT I
1520 FOR I = 1 TO NBIN + 1
1530 PRINT USING " ###.### "; X(I); Y(I)
1540 NEXT I
1550 RETURN
                                                                        

1620 END

SUB Pager
 PRINT "Push RETURN to CONTINUE, S to STOP";
 INPUT Q$
 IF Q$ = "S" THEN STOP
 PRINT CHR$(12);
END SUB